DECLARE SUB txtpalget (col%, r%, g%, b%)
DECLARE SUB txtpalset (col%, r%, g%, b%)
DEFINT A-Z
RANDOMIZE -TIMER
CONST PI = 3.14159265358#
DIM COSINUS(160) AS INTEGER
DIM RAND(255) AS INTEGER
DIM oldpal(16, 3)

FOR i = 1 TO 15
 txtpalget i, oldpal(i, 1), oldpal(i, 2), oldpal(i, 3)
NEXT i

'made by :

'omega , omega@inorbit.com
' buzz , buzz@ddsw.nl

FOR c = 0 TO 160
    COSINUS(c) = COS(c * 2 * PI / 80) * 16 + 16
NEXT

FOR c = 0 TO 255
    RAND(c) = INT(RND * 4) + 1
NEXT

WIDTH 80, 50
LOCATE , , 0

r = 3
g = 5
b = 5

FOR i = 0 TO 6
 txtpalset i, i * r, i * g, i * b
NEXT i

FOR i = 7 TO 15
 txtpalset i, (15 - i) * r, (15 - i) * g, (15 - i) * b
NEXT i

WAVESIDE1 = 1
WAVESIDE2 = 3
WAVESIDE3 = 2
R1 = 1
R2 = 10
R3 = 20
DEF SEG = &HB800
a$ = "Ίϊώ based ώϊ"
l = LEN(a$)
FOR i = 0 TO 8000 STEP 2
     POKE i, RND * 256
NEXT i
position = 8000
position = position - (l * 2)
FOR i = 1 TO l
     POKE position, ASC(MID$(a$, i, 1))
     position = position + 2
NEXT i
position = 7840
a$ = "ΙΝΝΝΝΝΝΝΝΝΝΝ"
l = LEN(a$)
position = position - (l * 2)
FOR i = 1 TO l
     POKE position, ASC(MID$(a$, i, 1))
     position = position + 2
NEXT i
DO
    WAVE1 = WAVE1 + WAVESIDE1
    IF WAVE1 >= 80 THEN
        WAVE1 = 0
        R1 = (R1 + 1) AND 255
        WAVESIDE1 = RAND(R1)
    END IF
    WAVE2 = WAVE2 + WAVESIDE2
    IF WAVE2 >= 80 THEN
        WAVE2 = 0
        R2 = (R2 + 2) AND 255
        WAVESIDE2 = RAND(R2)
    END IF
    WAVE3 = WAVE3 + WAVESIDE3
    IF WAVE3 >= 80 THEN
        WAVE3 = 0
        R3 = (R3 + 2) AND 255
        WAVESIDE3 = RAND(R3)
    END IF
    position = 1
    FOR i = 1 TO 2
    WAIT &H3DA, 8, 8
    WAIT &H3DA, 8, 0: NEXT i
    FOR y = 0 TO 49
        E = COSINUS(y + WAVE1)
        FOR x = 0 TO 79
            col = COSINUS(x + WAVE2) + E + COSINUS(x + WAVE3) + COSINUS(x + y)
            IF col > 127 THEN col = 127
            POKE position, col
            position = position + 2
        NEXT
    NEXT
    IF INP(96) = 1 THEN EXIT DO
LOOP
DEF SEG

FOR i = 1 TO 15
 txtpalset i, oldpal(i, 1), oldpal(i, 2), oldpal(i, 3)
NEXT i

SUB txtpalget (col, r, g, b)
c = col

SELECT CASE c
CASE 6
 c = 20
CASE 8 TO 15
 c = c + 48
END SELECT

 OUT &H3C7, c

 r = INP(&H3C9)
 g = INP(&H3C9)
 b = INP(&H3C9)

END SUB

SUB txtpalset (col, r, g, b)

c = col

SELECT CASE c
CASE 6
 c = 20
CASE 8 TO 15
 c = c + 48
END SELECT

 OUT &H3C8, c
 OUT &H3C9, r
 OUT &H3C9, g
 OUT &H3C9, b

END SUB